Handle taxa hierarchy in the topic aspect

Like you get on Google Scholar... this is the query that can be used:

#defaultView:Table
SELECT ?work ?work_label (count(?citing_work) as ?count) WHERE {
  ?work wdt:P2860 wd:Q27065423 .
  ?citing_work wdt:P2860 ?work . 
  ?work rdfs:label ?work_label . filter (lang(?work_label) = 'en')
} group by ?work ?work_label
order by desc(?count)
limit 20

Where you can replace wd:Q27065423 with $work

Maybe you can provide a link to the full text (P953) is that is given in the record, just below the title?

Use this query:

SELECT ?work ?work_label (COUNT(?citing_work) AS ?count) WHERE {
  ?work wdt:P1433 wd:Q6294930.
  ?citing_work wdt:P2860 ?work.
  ?work rdfs:label ?work_label.
  FILTER((LANG(?work_label)) = "en")
}
GROUP BY ?work ?work_label
ORDER BY DESC(?count)
LIMIT 20

Using the Journal of Cheminformatics (wd:Q6294930) as an example.

Histogram view for venue per suggestion of @egonw https://twitter.com/egonwillighagen/status/835776043239817216

The search form should be visible on all pages.

Add versioneer

The selector uses URIs, see https://tools.wmflabs.org/scholia/author/Q18921408 for instance. Labels should be used.

Change get_metadata in arxiv.py to use API.

Citation network for topics

Scholia generates bibtex files with UTF-8 characters that bibtex cannot understand. Bibtex's sorting and author name extraction fails. Either users are forced over to biber or something must be done, e.g., a conversion table and accent conversion.

Collaborating organization for organizations suggested by Egon Willighagen https://twitter.com/egonwillighagen/status/807230336224677888

select (count(distinct ?work) as ?count) ?affiliation2 ?affiliation2_label where {
  ?work (p:P50|p:P2093) ?author_statement . 
  ?author_statement ps:P50 wd:Q20895241 .
  ?author_statement pq:P1416 wd:Q19845644 .
  {
    ?work p:P2093 ?author2_statement . 
    ?author2_statement ps:P2093 ?author2 .
    ?author2_statement pq:P1416 ?affiliation2 .
  } UNION {
    ?work p:P50 ?author2_statement . 
    ?author2_statement ps:P50 ?author2 .
    ?author2_statement pq:P1416 ?affiliation2 .
  }
  ?affiliation2 rdfs:label ?affiliation2_label . filter (lang(?affiliation2_label) = 'en')
  FILTER (?affiliation2 != wd:Q19845644)
  FILTER (?author2 != wd:Q20895241)
} group by ?affiliation2 ?affiliation2_label
order by desc(?count) asc(?affiliation2_label)

The list of publications shows only P50-authors, - not P2093-authors. And the authors are not sorted according to P1545.

Scholia could have a page with sponsor/funder.

Again with JCheminf as example:

SELECT ?author ?author_label (count(?work) as ?count) WHERE {
  ?work wdt:P50 ?author ;
        wdt:P1433 wd:Q6294930.
  ?author rdfs:label ?author_label . filter (lang(?author_label) = 'en')
} group by ?author ?author_label
order by desc(?count)
limit 20

Collaborating institutions for author suggested by Egon Willighagen https://twitter.com/egonwillighagen/status/807230510267244544

select (count(distinct ?work) as ?count) ?affiliation2 ?affiliation2_label where {
  ?work (p:P50|p:P2093) ?author_statement . 
  ?author_statement ps:P50 wd:Q20895241 .
  ?author_statement pq:P1416 ?affiliation .
  ?affiliation rdfs:label ?affiliation_label . filter (lang(?affiliation_label) = 'en')
  {
    ?work p:P2093 ?author2_statement . 
    ?author2_statement ps:P2093 ?author2 .
    ?author2_statement pq:P1416 ?affiliation2 .
  } UNION {
    ?work p:P50 ?author2_statement . 
    ?author2_statement ps:P50 ?author2 .
    ?author2_statement pq:P1416 ?affiliation2 .
  }
  ?affiliation2 rdfs:label ?affiliation2_label . filter (lang(?affiliation2_label) = 'en')
  FILTER (?affiliation2 != ?affiliation)
  FILTER (?author2 != wd:Q20895241)
} group by ?affiliation2 ?affiliation2_label
order by desc(?count) asc(?affiliation2_label)

• occupations
• academic fields
• methods

Such that articles like
https://www.wikidata.org/wiki/Q21145375 (i.e. for which there is a P921 statement)
pop up in the scholia view for the objects of those P921 statements, i.e.
https://tools.wmflabs.org/scholia/author/Q92714
and
https://tools.wmflabs.org/scholia/author/Q4829027
for the above example.

e.g.
https://tools.wmflabs.org/scholia/Q2085381/
as an equivalent to
https://tools.wmflabs.org/scholia/publisher/ .

Allow traveling from one Scholia page to another one by replacing - optionally - the links to Wikidata items with links to Scholia profiles.

I set up a very basic version of a Scholia template:
https://www.wikidata.org/wiki/Template:Scholia ,
test corpus at
https://www.wikidata.org/wiki/User:Daniel_Mietchen/Bioinformatics .

For instance:

# Co-founders
select (count(?work) as ?count) ?sponsor ?sponsorLabel where {
  ?work wdt:P859 wd:Q22329431 .
  ?work wdt:P859 ?sponsor .
  filter (wd:Q22329431 != ?sponsor)
  service wikibase:label { bd:serviceParam wikibase:language "en,de,fr,es,jp,it,da,sv,zh" }
}
group by ?sponsor ?sponsorLabel
order by desc(?count)

Citation per year for author suggested by Egon Willighagen https://twitter.com/egonwillighagen/status/807281048006651904

#defaultView:BarChart
#defaultView:Table
SELECT ?year (count(distinct ?citing_work) as ?count) WHERE {
  ?work wdt:P50 wd:Q20895241 .
  ?citing_work wdt:P2860 ?work . 
  # to remove self-citations: minus { ?citing_work wdt:P50 wd:Q20895241 }
  ?citing_work wdt:P577 ?date .
  BIND(str(YEAR(?date)) AS ?year)
} group by ?year
order by desc(?year)    

The SPARQLs for the "venue" list the birthdates of workers, and uses:

(min(?birthdates) as ?birthdate)

But if multiple dates are given for someone, like one with only a year, the date is defaulted to the January 1, the minimum... it seems to me that "min(?birthdates)" returns the least precise information?

Missing distinct in Co-occurring topics

Non-humans should have curly braches in bibtex generation

For references whose Wikidata item has P275 set to an open license (i.e. CC BY or CC BY-SA) or CC0/PD, display the corresponding Creative Commons icon.

Show list of co-topics

If a SPARQL query times out, this currently produces an error that Scholia should catch and replace with a useful boilerplate message.

Likewise, if the SPARQL query produced no results, this should be stated in a standardized fashion.

Suborganization affiliation should be one or more: ?suborganization wdt:P361 wd:Q1269766 to ?suborganization wdt:P361+ wd:Q1269766

iframe height are too big for some query, leaving a lot a white space.

For instance, Max Planck Society
https://tools.wmflabs.org/scholia/organization/Q158085
should aggregate from across the different Max Planck Institutes but currently does not.

e.g. as per this sample query:

#defaultView:Table
SELECT ?work ?workLabel 
(min(?dates) as ?date) 
(sample(?pages_) as ?pages) 
(sample(?venue_labels) as ?venue) 
(sample(?license_labels) as ?license) 
(group_concat(?author_label; separator=", ") as ?authors)  
WHERE {
  ?work wdt:P50 wd:Q20980928 .
  ?work wdt:P50 ?author .
  ?author rdfs:label ?author_label . filter (lang(?author_label) = 'en')
  
  optional { ?work wdt:P577 ?dates }.
  optional { ?work wdt:P1104 ?pages_ }.
  optional { ?work wdt:P275 ?licenses }.
  optional { ?work wdt:P1433 ?venues . ?venues rdfs:label ?venue_labels . filter (lang(?venue_labels) = 'en') }.
  optional { ?work wdt:P275 ?licenses . ?licenses rdfs:label ?license_labels . filter (lang(?license_labels) = 'en') }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,fr,de,ru,es,zh,jp". }  
} group by ?work ?workLabel
order by desc(?date)    

For bar chart plotting years with zero count are not rendered. The SPARQL query can be modified to include zero count years.

This issue is also discussed on Stackoverflow: https://stackoverflow.com/questions/40454268/how-can-get-default-return-values-for-a-sparql-query-when-counting

"Citations by year" for authors should not be distinct on citing works

At least for works as not everything is published in English and translating publication titles seems wrong. Unfortunately I don't know how to support any language. I stumbled upon this because of https://www.wikidata.org/wiki/Q27044176. To support at least some other languages change

SERVICE wikibase:label { bd:serviceParam wikibase:language "en". } 

to

SERVICE wikibase:label { bd:serviceParam wikibase:language "en,fr,de,ru,es,zh,jp". } 

and/or try to get the title via title propert https://www.wikidata.org/wiki/Property:P1476.

@egonw suggest topics for journals https://twitter.com/egonwillighagen/status/815143507639828480

some inspiration in http://kitchingroup.cheme.cmu.edu/blog/2016/08/25/Automated-bibtex-entry-tweeting/ .

Too lazy for pull request; suggest using co-authors in sci articles AND books, using:

  VALUES ?type { wd:Q13442814 wd:Q571 } .
  ?work wdt:P31 ?type . 

A list of relevant journals on the topic page

as per the recent switch in practice on Wikidata.

For instance,
https://tools.wmflabs.org/scholia/topic/Q18123741
lists basically only papers directly annotated with P921=Q18123741, which is good, but it would be good to have an option (think
https://tools.wmflabs.org/scholia/topic/Q18123741&zoom=+2 )
to aggregate results from some subclasses of infectious diseases as well.
Conversely, it would be nice to be able to zoom out to diseases or medicine more generally.

In
https://www.wikidata.org/wiki/Template:Scholia ,
I have used
https://commons.wikimedia.org/wiki/File:Sonar_tracking_of_tungsten_ball_underneath_research_vessel_for_calibration_(16824332958).jpg but this is probably not what we want in the long term.

citations per author:

#defaultView:BarChart
select ?year (sum(?citations_per_author_) as ?citations_per_author) ?researcher_label where {
 {
    select ?researcher_label ?work ?year (count(distinct ?citing_work) / count(distinct ?researcher_of_paper) as ?citations_per_author_) where {
      { ?researcher wdt:P108 wd:Q24283660 . } union { ?researcher wdt:P1416 [ wdt:P361* wd:Q24283660 ] .  }
      ?work (wdt:P50|wdt:P2093) ?researcher_of_paper .
      # ?work wdt:P31 wd:Q13442814 .
      ?work wdt:P50 ?researcher .
      ?citing_work wdt:P2860 ?work .
      ?work wdt:P577 ?date . 
      bind(str(year(?date)) as ?year) 
      ?researcher rdfs:label ?researcher_label . filter(lang(?researcher_label) = 'en')
    } 
    group by ?work ?researcher_label ?year
  }
}
group by ?year ?researcher_label 
order by ?year

"Recently published works on the topic" may return redundant topics, because of missing distinct work around the union.

Publishers, organizations, funders could in principle all have some form of P921 display based on aggregation of article and/ or journal-level P921 statements.

It would probably good to enrich the "Edit query on Wikidata.org" links with brief documentation of the SPARQL queries, such that SPARQL and/ or Wikidata newbies can use them as a playground.

and turn them into hyperlinks

Investigate whether property paths instead of unions works better and change them and use them.

For instance, topic identification:

{ ?work wdt:P921/wdt:P31*/wdt:P279* wd:Q52 . }
union { ?work wdt:P921/wdt:P361+ wd:Q52 . }
union { ?work wdt:P921/wdt:P1269+ wd:Q52 . }

Property path:

?work wdt:P921/( wdt:P31*/wdt:P279* | wdt:P361+ | wdt:P1269+ ) wd:Q52 .

Specialized search page for "advanced" search where the category can be specified. It is started here: http://127.0.0.1:8100/search Missing functionality:

• Link from the search bar for enter, see #1460
• Display the label of the Wikidata item.
• Enable paging.
• Make the search "intelligent", so if a recognized pattern, e.g., arXiv identifier or DOI is entered/copy-pasted it will search with http://127.0.0.1:8100/arxiv-to-quickstatements
  • #1474