Pareto Chart about plotly.net HOT 6 CLOSED

#r "nuget: Plotly.NET"
open Plotly.NET
open Plotly.NET.TraceObjects

let labelAndValues = [
    
    "Child Care"      , 44.8 
    "Public Transport", 27.2 
    "weather"         , 19.6
    "Traffic"         , 56.
]

module Seq =
    let unzip keyValues =
        keyValues |> Seq.map fst
        , keyValues |> Seq.map snd

type Chart with
    static member Pareto(keysValues: seq<string * float>, ?Name: string, ?Label: string) =
        let orderedLabels, orderedValues =
            keysValues
            |> Seq.sortByDescending snd
            |> Seq.unzip
        
        let sum = orderedValues |> Seq.sum
        let topPaddingRatio = 0.05
        let cumulativeSum = 
            Seq.scan (+) 0. orderedValues
             |> Seq.skip 1
        
        let paretoValues = 
            Seq.zip orderedLabels cumulativeSum
            |> Seq.map (fun (label,value) -> label, value / sum * 100.) 
        
        let bars = Chart.Column(Seq.zip orderedLabels orderedValues,?Name=Name)
        
        let points = 
            Chart.Point(
                paretoValues
                , ShowLegend = false
                , Marker     = Marker.init(Size = 8, Color = Color.fromKeyword Black, Symbol = StyleParam.MarkerSymbol.Cross, Angle = 45.)
            )
            |> Chart.withAxisAnchor (Y = 2)
            
        let lines = 
            Chart.Line(
                paretoValues
                , Name       = "Cumulative %"
                , ShowLegend = true
            ) 
            |> Chart.withAxisAnchor (Y = 2)
            
        [bars;lines;points] 
        |> Chart.combine 
        |> Chart.withYAxisStyle (
                ?TitleText = Label
                , Id       = StyleParam.SubPlotId.YAxis 1
                , ShowGrid = false
                , MinMax   = (0.,sum * (1.+topPaddingRatio))
            )
        |> Chart.withYAxisStyle (
                TitleText    = "%"
                , Side       = StyleParam.Side.Right
                , Id         = StyleParam.SubPlotId.YAxis 2
                , MinMax     = (0.,100. * (1.+topPaddingRatio))
                , Overlaying = StyleParam.LinearAxisId.Y 1
            )


Chart.Pareto(labelAndValues, Name="Budget", Label="$") |> Chart.show