Floating point exception (AV) when using a shader (x64) about csfml HOT 12 CLOSED

program Circles;

uses
  SysUtils,
  SfmlGraphics,
  SfmlSystem,
  SfmlWindow;

var
  VertexShader, FragmentShader: PAnsiChar;
  RenderTargetHandle: PsfRenderTexture;
  TextureHandle: PsfTexture;
  WindowHandle: PsfRenderWindow;
  Event: TsfEvent;
  States: TsfRenderStates;
  CircleShaderHandle: PsfShader;
  SpriteHandle: PsfSprite;
begin
  States.BlendMode := sfBlendAlpha;
  States.Transform := sfTransformIdentity;

  VertexShader :=
    '#version 110'#10 +
    'precision lowp float;'#10 +
    ''#10 +
    'varying vec2 uv;'#10 +
    ''#10 +
    'void'#10 +
    'main() {'#10 +
    '  gl_Position = gl_ModelViewProjectionMatrix * gl_Vertex;'#10 +
    '  uv = vec2(gl_MultiTexCoord0);'#10 +
    '}';
  FragmentShader :=
    '#version 110'#10 +
    'precision lowp float;'#10 +
    ''#10 +
    'varying vec2 uv;'#10 +
    'uniform float Radius;'#10 +
    'uniform vec2 Position;'#10 +
    'uniform vec4 CircleColor;'#10 +
    ''#10 +
    'void'#10 +
    'main() {'#10 +
    '  vec4 color0 = CircleColor;'#10 +
    ''#10 +
    '  vec2 m = uv - Position;'#10 +
    '  float dist = Radius - sqrt(m.x * m.x + m.y * m.y);'#10 +
    ''#10 +
    '  float t = 0.0;'#10 +
    '  if (dist > 2.0)'#10 +
    '    t = 1.0;'#10 +
    '  else if (dist > 0.0)'#10 +
    '    t = 0.5 * dist;'#10 +
    ''#10 +
    '  color0.a = t * color0.a;'#10 +
    '  gl_FragColor = color0;'#10 +
    '}';
  CircleShaderHandle := sfShader_createFromMemory(VertexShader, FragmentShader);
  States.Shader := CircleShaderHandle;

  RenderTargetHandle := sfRenderTexture_create(800, 600, False);
  TextureHandle := sfRenderTexture_getTexture(RenderTargetHandle);

  // Create the main Window
  WindowHandle := sfRenderWindow_create(sfVideoMode(800, 600),
    PAnsiChar('SFML Shader'), [sfTitleBar, sfClose], nil);

  // Start the loop
  while sfRenderWindow_isOpen(WindowHandle) do
  begin
    // Process events
    while sfRenderWindow_pollEvent(WindowHandle, Event) do
    begin
      if Event.EventType = sfEvtClosed then
        sfRenderWindow_close(WindowHandle);
    end;

    SpriteHandle := sfSprite_create;
    try
      sfSprite_setTexture(SpriteHandle, TextureHandle, False);
      sfRenderWindow_drawSprite(WindowHandle, SpriteHandle, nil);
    finally
      sfSprite_destroy(SpriteHandle);
    end;

    sfShader_setColorParameter(CircleShaderHandle, 'CircleColor',
      sfColor_fromRGBA(Random($FF), Random($FF), Random($FF), Random($FF)));
    sfShader_setFloatParameter(CircleShaderHandle, 'Radius', 200 * Random);
    sfShader_setFloat2Parameter(CircleShaderHandle, 'Position', 800 * Random, 600 * Random);

    SpriteHandle := sfSprite_create;
    try
      sfSprite_setTexture(SpriteHandle, TextureHandle, False);
      sfRenderTexture_drawSprite(RenderTargetHandle, SpriteHandle, @States);
    finally
      sfSprite_destroy(SpriteHandle);
    end;

    // Finally, display the rendered frame on screen
    sfRenderWindow_display(WindowHandle);
  end;
end.