Timer Events for animation. about reflex-sdl2 HOT 5 CLOSED

--------------------------------------------------------------------------------
data TimerData = TimerData { timerDataCode      :: Int32
                           , timerDataTimestamp :: Timestamp
                           }


toTimerData :: Int32 -> RegisteredEventData -> Timestamp -> IO (Maybe TimerData)
toTimerData eventCode rdat ts
  | eventCode == registeredEventCode rdat =
    return $ Just $ TimerData eventCode ts
  | otherwise = return Nothing


fromTimerData :: TimerData -> IO RegisteredEventData
fromTimerData (TimerData code _) =
  return $ emptyRegisteredEvent{ registeredEventCode = code }


getRecurringTimerEventWithEventCode
  :: ReflexSDL2 r t m => Int32 -> Int -> m (Event t ())
getRecurringTimerEventWithEventCode eventCode millis = do
  -- Register the timer event as a user event so it will wake `waitEvent` when
  -- pushed into the queue.
  let toData = toTimerData eventCode
  mayReg <- registerEvent toData fromTimerData
  case mayReg of
    Nothing -> return ()
    Just (RegisteredEventType push _) -> liftIO $ void $ async $ fix $ \loop -> do
      threadDelay $ millis * 1000
      ts <- ticks
      push (TimerData eventCode ts) >>= \case
        EventPushSuccess   -> return ()
        EventPushFiltered  -> putStrLn "push filtered"
        EventPushFailure t -> print t
      loop
  -- Filter the user event to only fire when the incoming code matches.
  evUser <- getUserEvent
  return $ fmapMaybe (guard . (eventCode ==) . userEventCode) evUser