MFA Push Verification Polling not working. about okta-auth-java HOT 3 CLOSED

#! /usr/bin/env groovy
import com.okta.authn.sdk.AuthenticationStateHandler
import com.okta.authn.sdk.client.AuthenticationClient
import com.okta.authn.sdk.client.AuthenticationClients
import com.okta.authn.sdk.AuthenticationStateHandlerAdapter
import com.okta.authn.sdk.impl.resource.DefaultVerifyPassCodeFactorRequest
import com.okta.authn.sdk.resource.AuthenticationResponse
import com.okta.authn.sdk.resource.Factor
import com.okta.authn.sdk.resource.VerifyFactorRequest
import groovy.transform.Field

import java.util.concurrent.CompletableFuture
import java.util.concurrent.Future

@Grapes([
        @Grab(group='com.okta.authn.sdk', module='okta-authn-sdk-api', version='0.1.0'),
        @Grab(group='com.okta.authn.sdk', module='okta-authn-sdk-impl', version='0.1.0'),
        @Grab(group='com.okta.sdk', module='okta-sdk-httpclient', version='1.2.0')
//        @Grab(group='ch.qos.logback', module='logback-classic', version='1.2.3')
])

@Field
def oktaUrl = System.getenv('OKTA_URL')
@Field
def oktaApiKey = System.getenv('OKTA_API_KEY')
@Field
def oktaUserName = System.getenv('OKTA_USERNAME')
@Field
String oktaPassword = System.getenv('OKTA_PASSWORD')

def main() {
    // Set the api token for the okta client to use, why can't I pass it into the client, wtf?
    System.setProperty("okta.client.token", oktaApiKey)

    AuthenticationClient client = AuthenticationClients.builder()
            .setOrgUrl(oktaUrl)
            .build()

    String username = oktaUserName ? oktaUserName : System.console().readLine('What is your Okta username? ')

    char[] passwordCharArr
    if (!oktaPassword) {
        print "What is your Okta password? "
        passwordCharArr = System.console().readPassword()
    } else {
        passwordCharArr = oktaPassword.toCharArray()
    }

    CompletableFuture<AuthenticationResponse> authenticationResponseCompletableFuture = new CompletableFuture<>()
    AuthenticationStateHandler stateHandler = new MyAuthenticationStateHandler(client, authenticationResponseCompletableFuture)

    client.authenticate(username, passwordCharArr, null, stateHandler)

    AuthenticationResponse authResponse = authenticationResponseCompletableFuture.get()

    println("Final auth status:: ${authResponse.getStatus()}")

}

class MyAuthenticationStateHandler extends AuthenticationStateHandlerAdapter {

    AuthenticationClient client
    CompletableFuture<AuthenticationResponse> authenticationResponseFuture;

    MyAuthenticationStateHandler(AuthenticationClient client, Future<AuthenticationResponse> authenticationResponseFuture) {
        this.client = client
        this.authenticationResponseFuture = authenticationResponseFuture
    }

    void handleMfaChallenge(AuthenticationResponse mfaChallengeResponse) {
        if (! (mfaChallengeResponse.getFactors().get(0).get("factorType") == "push")) {
            return
        }
        println "waiting for factor to be verified"

        sleep(1000)

        VerifyFactorRequest request = client.instantiate(VerifyFactorRequest.class)
        request.setStateToken(mfaChallengeResponse.getStateToken())

        def id = mfaChallengeResponse.getFactors().get(0).getId()

        if (mfaChallengeResponse.getFactorResult() == "REJECTED") {
            println "user failed to authenticate"
            authenticationResponseFuture.complete(mfaChallengeResponse)
            return
        }

        client.verifyFactor(id, request, this)
    }

    @Override
    void handleSuccess(AuthenticationResponse successResponse) {
        println "successfully approved"
        authenticationResponseFuture.complete(successResponse)
    }

    @Override
    void handleUnauthenticated(AuthenticationResponse unauthenticatedResponse) {
        println "user failed to authenticate"
        authenticationResponseFuture.complete(unauthenticatedResponse)
    }

    void handleMfaRequired(AuthenticationResponse mfaRequiredResponse) {
        println "MFA is require found the following factors:"
        mfaRequiredResponse.getFactors().eachWithIndex { Factor factor, int i ->
            println "${i}: ${factor.getProvider()} ${factor.getType()}"
        }
        def factorSelection = Integer.valueOf(System.console().readLine('Select factor to verify? '))
        def factor = mfaRequiredResponse.getFactors().get(factorSelection)

        def type = factor.getType().toString()
        switch (type) {
            case "token:software:totp":
                handleCode(factor, mfaRequiredResponse.getStateToken())
                break
            case "sms":
                triggerCodeGeneratingFactorAndPromptForCode(factor, mfaRequiredResponse.getStateToken())
                break
            case "call":
                triggerCodeGeneratingFactorAndPromptForCode(factor, mfaRequiredResponse.getStateToken())
                break
            case "push":
                handlePush(factor, mfaRequiredResponse.getStateToken())
                break
            default:
                throw new RuntimeException("Unknown factor type: ${type}")
        }

    }

    void handleUnknown(AuthenticationResponse typedUnknownResponse) {
        println("unknown / unhandled status: ${typedUnknownResponse.getStatus()} res: ${typedUnknownResponse}")
        authenticationResponseFuture.complete(typedUnknownResponse)
    }

    def triggerCodeGeneratingFactorAndPromptForCode(Factor factor, String stateToken) {
        client.challengeFactor(factor.getId(), stateToken, this)
        def code = System.console().readLine('Enter code: ')
        verifyCode(code, factor.getId(), stateToken)
    }

    def handleCode(Factor factor, String stateToken) {
        def otp = System.console().readLine('Enter one time code: ')
        verifyCode(otp, factor.getId(), stateToken)
    }

    def handlePush(Factor factor, String stateToken) {
        println("Triggering challenge")
        client.challengeFactor(factor.getId(), stateToken, this)
    }

    def verifyCode(String code, id, stateToken) {
        DefaultVerifyPassCodeFactorRequest request = client.instantiate(DefaultVerifyPassCodeFactorRequest.class)
        request.setPassCode(code)
        request.setStateToken(stateToken)

        client.verifyFactor(id, request, this)
    }
}

main()