renderRssDocument doesn't call renderRssItem? about rss-conduit HOT 6 CLOSED

{-# LANGUAGE OverloadedLists, OverloadedStrings #-}
module Main where

import Data.Monoid (mempty, (<>))
import qualified Data.ByteString as B
import qualified Data.Text as T
import qualified Text.RSS.Types as RSST
import qualified Text.RSS.Conduit.Render as RSSR
import qualified Text.XML.Stream.Render as XMLR
import qualified Data.Conduit.List as CL
import qualified URI.ByteString as URIB
import qualified Data.Time.Clock as Clock
import qualified Data.Time.Calendar as Calendar
import           Data.Conduit (ConduitM, runConduit, (=$=))
import           Data.Void (Void)
import           Control.Monad.Identity (Identity, runIdentity)
import qualified Data.ByteString.Builder as BB
import qualified Data.ByteString.Lazy as BL


main = BL.putStrLn (renderFeed feed)

feed :: RSST.RssDocument
feed = RSST.RssDocument {
        RSST.documentVersion = [2,0],
        RSST.channelTitle = "Title",
        RSST.channelLink = https "example.com",
        RSST.channelDescription = "foo",
        RSST.channelItems = [item],
        RSST.channelLanguage = "en-US",
        RSST.channelCopyright = "Copyright 1999",
        RSST.channelManagingEditor = "Bob Bar",
        RSST.channelWebmaster = "Bill Baz",
        RSST.channelPubDate = Just today,
        RSST.channelLastBuildDate = Just today,
        RSST.channelCategories = categories,
        RSST.channelGenerator = "AbstractRSSAdapterFactoryBean 2.7",
        RSST.channelDocs = Nothing,
        RSST.channelCloud = Nothing,
        RSST.channelTtl = Just 60, -- minutes
        RSST.channelImage = Nothing,
        RSST.channelRating = "Inappropriate for all ages",
        RSST.channelTextInput = Nothing,
        RSST.channelSkipHours = mempty,
        RSST.channelSkipDays = mempty
    }
    where
    today = Clock.UTCTime {Clock.utctDay = Calendar.fromGregorian 3000 8 12, Clock.utctDayTime = 0}
    categories = [RSST.RssCategory "Foo" "Bar"]

item = RSST.RssItem {
        RSST.itemTitle = "My Item",
        RSST.itemLink = Just (https "example.com/item1"),
        RSST.itemDescription = "Some stuff",
        RSST.itemAuthor = "[email protected]",
        RSST.itemCategories = [],
        RSST.itemComments = Nothing,
        RSST.itemEnclosure = [],
        RSST.itemGuid = Just (RSST.GuidText "12345"),
        RSST.itemPubDate = Just (Clock.UTCTime {Clock.utctDay = Calendar.fromGregorian 2020 1 1, Clock.utctDayTime = 0}) ,
        RSST.itemSource = Nothing
    }

renderFeed :: RSST.RssDocument -> BL.ByteString 
renderFeed = BB.toLazyByteString . runIdentity . runConduit . builder
    where
    builder :: RSST.RssDocument -> ConduitM () Void Identity BB.Builder
    builder feed = RSSR.renderRssDocument feed 
               =$= XMLR.renderBuilder (XMLR.def {XMLR.rsPretty = True}) 
               =$= CL.fold (<>) "<?xml version=\"1.0\" encoding=\"UTF-8\"?>\n"

https :: B.ByteString -> RSST.RssURI
https link = RSST.RssURI (URIB.URI (URIB.Scheme "https") Nothing ("//" <> link) (URIB.Query []) Nothing)