Game controller not recognized about hashlink HOT 10 OPEN

package tools;

class Joystick {

    public var index : Int = -1;
    public var connected(default, null) = true;
    public var values : Array<Float> = [];
    public var buttons : Array<Bool> = [];
    public var prevValues : Array<Float> = [];
    public var xAxis(get,never) : Float;
    public var yAxis(get,never) : Float;
    public var rxAxis(get,never) : Float;
    public var ryAxis(get,never) : Float;
    public var axisDeadZone : Float = 0.1;
    #if hl
    public static var ANALOG_BUTTON_THRESHOLDS = { press: 0.3, release: 0.25 };
    #end

    #if hlsdl
    public var d : sdl.Joystick;
    #end
    var rawXAxis : Float = 0.;
    var rawYAxis : Float = 0.;
    var rawRXAxis : Float = 0.;
    var rawRYAxis : Float = 0.;
    var prevButtons : Array<Bool> = [];

    static var sticks : Map<Int, Joystick> = new Map();
    static var waitPad : Joystick -> Void;
    static var initDone = false;

    function get_xAxis() {
        if( rawXAxis*rawXAxis + rawYAxis*rawYAxis < axisDeadZone*axisDeadZone ) return 0.;
        return rawXAxis;
    }

    function get_yAxis() {
        if( rawXAxis*rawXAxis + rawYAxis*rawYAxis < axisDeadZone*axisDeadZone ) return 0.;
        return rawYAxis;
    }

    function get_rxAxis() {
        if( rawRXAxis*rawRXAxis + rawRYAxis*rawRYAxis < axisDeadZone*axisDeadZone ) return 0.;
        return rawRXAxis;
    }

    function get_ryAxis() {
        if( rawRXAxis*rawRXAxis + rawRYAxis*rawRYAxis < axisDeadZone*axisDeadZone ) return 0.;
        return rawRYAxis;
    }

    function new() {
    }

    public function isDown( button : Int ) {
        return buttons[button];
    }

    public function isPressed( button : Int ) {
        return buttons[button] && !prevButtons[button];
    }

    public function isReleased( button : Int ) {
        return !buttons[button] && prevButtons[button];
    }

    public dynamic function onDisconnect(){
    }

    inline function _setAxis( axisId : Int, value : Int ){
        var v = value / 0x7FFF;

        _detectAnalogButton(axisId, v);

        // Invert Y axis
        if( axisId == 1 || axisId == 3 )
            values[ axisId ] = -v;
        else
            values[ axisId ] = v;

        if( axisId == 0 )
            rawXAxis = v;
        else if( axisId == 1 )
            rawYAxis = v;
        else if( axisId == 2 )
            rawRXAxis = v;
        else if( axisId == 3 )
            rawRYAxis = v;
    }

    #if hl
    inline function _setButton( btnId : Int, down : Bool ){
        buttons[ btnId ] = down;
        values[ btnId ] = down ? 1 : 0;
    }

    function _detectAnalogButton(index: Int, v: Float) {
        if(v > ANALOG_BUTTON_THRESHOLDS.press && v > values[index]) {
            buttons[ index ] = true;
        }
        if(v < ANALOG_BUTTON_THRESHOLDS.release && v < values[index]) {
            buttons[ index ] = false;
        }
    }
    #end

    static function initPad( index ){
        var sp = new sdl.Joystick( index );
        if( @:privateAccess sp.ptr == null )
            return;
        var j = new Joystick();
        j.index = sp.id;
        j.d = sp;
        var prev = sticks.get( j.index );
        if (prev != null) {
            sticks.remove( j.index );
            prev.d.close();
            prev.connected = false;
            prev.onDisconnect();
        }
        sticks.set( j.index, j );
        for( axis in 0...6 )
            j._setAxis( axis, sp.getAxis(axis) );
        for( button in 0...15 )
            j._setButton( button + 6, sp.getButton(button) );
        waitPad( j );
    }

    static function syncPads(){
        for( p in sticks ) {
            for( i in 0...p.buttons.length ) {
                p.prevButtons[i] = p.buttons[i];
                p._setButton( i, p.d.getButton(i) );
            }
            for( i in 0...p.values.length ) {
                p.prevValues[i] = p.values[i];
                p._setAxis( i, p.d.getAxis(i) );
            }
        }
    }

    public static function wait( onPad : Joystick -> Void ) {
        #if js
        if( !js.Browser.supported )
            return;
        #end
        waitPad = onPad;
        #if hlsdl
        if( !initDone ) {
            initDone = true;
            var c = @:privateAccess sdl.Joystick.joyCount();
            for( idx in 0...c )
                initPad( idx );
            haxe.MainLoop.add(syncPads);
        }
        #elseif (hldx || usesys)
        if( !initDone ){
            initDone = true;
            sdl.Joystick.init();
            haxe.MainLoop.add(syncPads);
        }
        #elseif js
        if( !initDone ) {
            initDone = true;
            js.Browser.window.addEventListener("gamepadconnected", function(p) {
                var pad = new hxd.Pad();
                pad.d = p.gamepad;
                pad.config = pickConfig(pad.d.id);
                pad.index = pad.d.index;
                pads.set(pad.d.index, pad);
                waitPad(pad);
            });
            js.Browser.window.addEventListener("gamepaddisconnected", function(p) {
                var pad = pads.get(p.gamepad.index);
                if( pad == null ) return;
                pads.remove(p.gamepad.index);
                pad.connected = false;
                pad.onDisconnect();
            });
            #if !manual_sync_pad
            haxe.MainLoop.add(syncPads);
            #end
        }
        #end
    }

}